Wikiprojekti:Wiki Loves Monuments/kohteet/SPARQL-kyselyt

Vuoden 2022 SPARQL-kysely

SELECT DISTINCT ?q ?location ?image ?commonscat ?geoshape 
(COALESCE(?p4009, ?mainitem_p4009) as ?p4009)
(COALESCE(?p5310, ?mainitem_p5310) as ?p5310)
?p5313 
(COALESCE(?p4106, ?mainitem_p4106) as ?p4106) 
?p8355 
?qLabel_fi
?desc_fi
?sitelink_fi

?qLabel_sv
?desc_sv
?sitelink_sv

?qLabel_en
?desc_en
?sitelink_en

?qLabel_se
?desc_se
?sitelink_se

?qLabel_sms
?desc_sms
?sitelink_sms

?qLabel_smn
?desc_smn
?sitelink_smn

WITH {
SELECT ?q (SAMPLE(?location) as ?location) 
  WHERE {

  ?q wdt:P625 ?location . 
  {
     ?q wdt:P1435 ?p1435 .
     ?q wdt:P17 wd:Q33 .
  }
  UNION
  { 
     ?mainitem wdt:P1435 ?p1435 .
     ?mainitem wdt:P17 wd:Q33 .
     ?q wdt:P361* ?mainitem .
     ?q wdt:P17 wd:Q33 .
  }
  FILTER (?p1435 NOT IN ( wd:Q31027091, wd:Q65967032, wd:Q19683138 ) )
  FILTER NOT EXISTS {?q wdt:P5008 wd:Q113577693 } 
  }
  GROUP BY ?q
  LIMIT 125000
} AS %items
WHERE {
  INCLUDE %items
  
  OPTIONAL { ?q wdt:P3896 ?geoshape } 
  OPTIONAL { ?q wdt:P18 ?image }  
  OPTIONAL { ?q wdt:P373 ?commonscat }  
  OPTIONAL { ?q wdt:P4009 ?p4009 }  
  OPTIONAL { ?q wdt:P5310 ?p5310 }  
  OPTIONAL { ?q wdt:P5313 ?p5313 }  
  OPTIONAL { ?q wdt:P4106 ?p4106 }  
  OPTIONAL { ?q wdt:P8355 ?p8355 }  
  OPTIONAL { ?q rdfs:label ?qLabel_fi . FILTER(LANG(?qLabel_fi) = 'fi') } 
  OPTIONAL { ?q schema:description ?desc_fi . FILTER(LANG(?desc_fi) = 'fi') }  

  OPTIONAL { ?q rdfs:label ?qLabel_sv . FILTER(LANG(?qLabel_sv) = 'sv') } 
  OPTIONAL { ?q schema:description ?desc_sv . FILTER(LANG(?desc_sv) = 'sv') }  

  OPTIONAL { ?q rdfs:label ?qLabel_en . FILTER(LANG(?qLabel_en) = 'en') } 
  OPTIONAL { ?q schema:description ?desc_en . FILTER(LANG(?desc_en) = 'en') }  

  OPTIONAL { ?q rdfs:label ?qLabel_se . FILTER(LANG(?qLabel_se) = 'se') } 
  OPTIONAL { ?q schema:description ?desc_se . FILTER(LANG(?desc) = 'se') }  

  OPTIONAL { ?q rdfs:label ?qLabel_sms . FILTER(LANG(?qLabel_sms) = 'sms') } 
  OPTIONAL { ?q schema:description ?desc_sms . FILTER(LANG(?desc_sms) = 'sms') }  

  OPTIONAL { ?q rdfs:label ?qLabel_smn . FILTER(LANG(?qLabel_smn) = 'smn') } 
  OPTIONAL { ?q schema:description ?desc_smn . FILTER(LANG(?desc_smn) = 'smn') } 
  
  OPTIONAL { ?sitelink_fi schema:isPartOf <https://fi.wikipedia.org/>; schema:about ?q; }
  OPTIONAL { ?sitelink_sv schema:isPartOf <https://sv.wikipedia.org/>; schema:about ?q; }
  OPTIONAL { ?sitelink_en schema:isPartOf <https://en.wikipedia.org/>; schema:about ?q; }  
  OPTIONAL { ?sitelink_se schema:isPartOf <https://se.wikipedia.org/>; schema:about ?q; }  
  OPTIONAL { ?sitelink_sms schema:isPartOf <https://incubator.wikimedia.org/wiki/Wp/sms>; schema:about ?q; }  
  OPTIONAL { ?sitelink_smn schema:isPartOf <https://sms.wikipedia.org/>; schema:about ?q; }  
  
  OPTIONAL {
     ?q wdt:P361 ?mainitem .
     ?mainitem wdt:P4009 ?mainitem_p4009   
  }
  OPTIONAL {
     ?q wdt:P361 ?mainitem .
     ?mainitem wdt:P5310 ?mainitem_p5310   
  }
  OPTIONAL {
     ?q wdt:P361 ?mainitem .
     ?mainitem wdt:P4106 ?mainitem_p4106   
  }
}

Kokeile